Makapu@BlackSheep-LSL

久しぶりのスクリプトの記事です。
nyagos kiddさんから以下のような質問がありましたので、これに関連してEmail機能について書きたいと思います。

一つ教えて欲しいのですが、IMにより起動するスクリプトを作りたいと考えているのですがListenのチャンネルでそのような設定はあるのでしょうか？もしご存知でしたら教えてください
Posted by nyagos kidd at 2007年05月22日 00:46

IMを使いたい理由と代替案

まずこの質問への答えですが、残念ながらオブジェクト（スクリプト）はＩＭを受信できません。従ってＩＭに反応するようなスクリプトは作ることができません。

nyagosさんご本人に確認していないので、あくまでも推測ですが、スクリプトに指示を出すのにIMを使いたい理由にはどんなものがあるでしょうか。

一つには、IMの「内緒話」という特性に注目し、
「他の人にコマンドを見せたくない」
という理由があるかもしれません。
これであれば、listenのチャンネルを他の人にわからないようなチャンネル（例えば1342とか）に設定すれば、コマンドを人の目から隠すことができます。
スクリプトにコマンドを送るときは、「/1342 command」のように発言すればＯＫです。この発言は通常他の人には見えません。
listenの使い方については聞き耳を立てる（初級スクリプト第七回）を参照して下さい。

IMを使いたい理由としてもう一つ考えられるのは、
「遠く離れたところから操作したい」
というのもあるでしょう。
IMは距離が関係ないですから、どこからでもメッセージを送ることができます。
もしもIMをスクリプトで受信できるなら、セカンドライフ上のどこに居ても操作可能なスクリプトを作ることができるわけです。

ですが、先に述べたように、スクリプトではIMを受信することができません。
その代替案として、今回説明するEmailの機能が利用できます。

Email機能

セカンドライフではEmailを利用した機能がいくつか存在します。

例えば、オフラインのときに受けたIMをEmailに転送する機能です。
私がセカンドライフに接続していないとき、誰かが私に対してIMすると、そのメッセージはEmailに転送されてきます（転送はデフォルトでは無効になっていたかと思います）。
このとき送信されてくるEmailアドレスは、「セッションのUUID@im.secondlife.com」という一時的なアドレスです。
このアドレスにメールを返すと、IMを送ってきた人にメッセージがIMとして届きます。
つまり、
「IM」ー「Email」間でやり取りができるわけです。
この一時的なメールアドレスを使えるのはIMを受け取ってから5日間の間だけです。
また、IMからEmailには日本語を遅れますが、EmailからIMには日本語は送れないという難点もあります（2007/5月現在）。

さらに、スクリプトからEmailを扱う方法もあります。

セカンドライフのオブジェクトは一つ一つが実はEmailアドレスを持っていて、スクリプトを使うとEmailの送受信ができます。
各オブジェクトのEmailアドレスは「オブジェクトのUUID@lsl.secondlife.com」です。
例えばオブジェクトのUUIDが"a311ce4d-e755-f148-7999-56f289ca3f3b"だとしたら、Emailアドレスは「a311ce4d-e755-f148-7999-56f289ca3f3b@lsl.secondlife.com」になります。

オブジェクトのUUIDはllGetKey()関数で調べられます。
従って、以下のユーザー関数は、オブジェクトのEmailアドレスを取得します。

string get_email_address(){
  return (string)llGetKey() + "@lsl.secondlife.com";
}

default {
  state_entry(){
    llWhisper(0, get_email_address());
  }
}

Emailの送信には、llEmail関数を使います。

  llEmail(string address, string subject, string message)

引数は単純です。
addressには送信先のEmailアドレスを指定します。
subjectはEmailのタイトルです。
messageはEmailの本文になります。

タイトルと本文の長さは、合わせてだいたい4096文字くらいまでです。
実際にはオブジェクト名や送信元SIM名、位置などの情報が追加されるため、4000字よりも少々少なくなります。
しかしながら、スクリプトによるEmailの受信時には、タイトルは78文字、本文は1000文字までという制限があります（後述）。
ですので、4000字程度まで送れるとは言っても、スクリプト間の通信に使う際には1000文字程度が限界値です。

Emailを受信する際には、llGetNextEmail関数を使います。
この関数は「メールが届いていないかどうかをチェックする」関数です。

  llGetNextEmail(string address, string subject)

引数のaddressは送信元Emailアドレスを指定します。
subjectはEmailタイトルです。
例えば、
  llGetNextEmail("hoge@hoge.com", "hogera");
このようにした場合、"hoge@hoge.com"というアドレスから"hogera"というタイトルのメールが届いていないかどうかをチェックします。
全てのメールをチェックしたい場合には、addressとsubjectを空白文字にします。
  llGetNextEmail("", "");
こうすると、あらゆる送信元のあらゆるタイトルをチェックします。

チェックした結果、Emailが届いていた場合は、emailイベントが発生します。
emailイベントは以下のようなイベントです。

  email(string time, string address, string subj, string message, integer num_left) {
     // 処理
  }

引数が多いですが、難しいものは特にないと思います。
timeは受信時刻、addressは送信元アドレス、subjはEmailのタイトル、messageは本文です。
num_leftには「残り何通のメールがあるか」を示す数値が入ってきます。
残りのメールが無ければ0ですね。

さて、ここで受信されるEmailのタイトルと本文には少々制限があります。
タイトルは78文字、本文は1000文字です。
さらに、本文にはヘッダ情報と言う付加情報が付いています。
例えば他のオブジェクトから送られてきたEmailですと、以下のようなヘッダ情報が付きます。

Object-Name: Kappa head
Region: Walden (254976, 256000)
Local-Position: (244, 122, 21)

hi, jack!

最初の3行がヘッダ情報です。
1行空いて、最後の行がメッセージ本文になります。

ヘッダの1行目はEmailを送信してきたオブジェクトの名前が入ります。
この例では"Kappa head"という名前のオブジェクトからEmailが送信されてきたことになります。
2行目は送信元のSIMの情報です。"Walden"という名前のSIMから送信されています。
3行目はSIM内の送信位置です。座標244, 122, 21から送信されているということです。

メッセージ本文は「hi, jack!」（よぉ、ジャック！）です。
このあとおもむろに襲撃が始まりそうなメッセージです。

Emailスクリプト

では、Emailを受信するスクリプトを作ってみます。
ポイントはllGetNextEmail関数の使い方です。
どのように使うか見てみましょう。

default {
  state_entry() {
    llOwnerSay("My Email Address is " + (string)llGetKey() + "@lsl.secondlife.com");
    llSetTimerEvent(3.0);
  }

  timer() {
    llGetNextEmail("", "");
  }

  email(string time, string address, string subj, string message, integer num_left) {
    llSetTimerEvent(0.0);
    llOwnerSay("Mail Recv:");
    llOwnerSay("Time:" + time);
    llOwnerSay("From:" + address);
    llOwnerSay("Subject:" + subj);
    llOwnerSay("Message:" + message);
    llSetTimerEvent(3.0);
  }
}

まず最初に、スクリプトがスタートするとオブジェクトのEmailアドレスを表示するようにしました。
そしてタイマーを3秒間隔にセットしています。

タイマーイベントの中で、llGetNextEmail関数を使ってEmailが着ていないかどうかチェックをしています。
こうすることで3秒間隔でEmailのチェックが行われるわけです。

Emailが届いていると、emailイベントが発生します。
ここでは単に届いたメールの内容をオーナーに報告するだけにしてありますが、特定のタイトルや本文に応じて何か処理をするようにすることもできます。

email(string time, string address, string subj, string message, integer num_left) {
  llSetTimerEvent(0.0);
  if (subj == "jibaku"){
    // Emailのタイトルが"jibaku"だったときに何か処理する
  }
}

こんなふうにしてやれば、セカンドライフのどこからでも自爆スイッチをONにできます。
いや、意味があるかどうかは知らないですが（＾＾；

ついでに送信用スクリプトも書いてみましょう。

string email_address="a311ce4d-e755-f148-7999-56f289ca3f3b@lsl.secondlife.com";

default {
  touch_start(integer detected){
        llEmail(email_address, "jibaku", "That pot is very nice!");
    }
}

email_addressの定義は変えてください。
このまま動かすと、どこにメール送るかわかりません（＾＾；

タッチすると、email_addressに指定したアドレスにメールを送ります。
タイトルは"jibaku"。
本文は"That pot is very nice!"（あの壺は良いものだ！）です。

試しに先ほど作った受信用のスクリプトのEmailアドレスを使い、メールを送信・受信してみて下さい。
メールの送信には20秒ほどかかりますが、どこのSIMからでもメッセージが送れることが確認できるかと思います。

※注意！
受信用のオブジェクトをSIMの外に持ち出すと、UUIDが変わってしまうことがあります。
UUIDが変わるということは、Emailアドレスも変わりますので、その際は改めてUUIDを調べる必要があります。