Makapu@BlackSheep-LSL

基本的な記事が続いているので、たまには中級者向けのスクリプトについても書いておこうと思います。
スクリプトのリモートロードについての記事です。

例えば・・・いろいろとスクリプトを駆使して面白い商品を作ったとします。
しかし、うっかり見落としていたバグやlslの仕様変更などで、欠陥商品になることも多々あります。
また、新たに機能を追加して、商品をバージョンアップするようなこともあるでしょう。
そのような時、すでに売れてしまった商品をどうしますか？

買ってくれた人全てを把握しておいて、新しい商品を送付するというのも、商売人としては誠意あるスタンスです。
ですが商品の数が増えてきたり、100個や200個が売れる人気商品ともなると、顧客をいちいち管理しておくことも難しくなってきます。
バグ対応やバージョンアップは何かと面倒な作業ですよね・・・。

そんなときに便利なのがスクリプトのリモートロードです。

スクリプトのリモートロード

実はlslには、オブジェクトに入っているスクリプトを書き換える関数が用意されています。
あんまり使っている人を見かけないのですが・・・これを使うとスクリプトのBugFixやバージョンアップを自動化できます。

簡単にその仕組みを図示してみます。



他のprim内のスクリプトを書き換えたり、新たなスクリプトを追加したりする仕組みのことをスクリプトのリモートロードと言います。
このリモートロードを行う際には、PINという特殊な識別番号を設定する必要があります。
というのも、何でもかんでもリモートロードを可能にしてしまうとセキュリティの面で大きな問題になってきますので、primに設定されているPINがわからなければロードできないようになっているのです。
PINというのは、リモートロードを行う際のパスワードみたいなものだと考えておくとわかりやすいかもしれません。

なお、PINはinteger型の数値です。
これを設定するには、llSetRemoteScriptAccessPin関数を使います。

  llSetRemoteScriptAccessPin(integer pin);

この関数によって指定されたPINはオブジェクトに対して設定されます。
オブジェクト内に複数のスクリプトがあったとしても、全て同じPINでリモートロードが可能です。
さらに言えば、llSetRemoteScriptAccessPin関数を実行したスクリプト自体が削除されたとしても、PINの設定自体は残ります。

つまり、スクリプトをあとから書き換えたい場合は、以下のようなスクリプト用意してオブジェクトに放り込んでおけば良いのです。

integer pin = 12345;

default {
  state_entry(){
    llSetRemoteScriptAccessPin(pin);
    llRemoveInventory(llGetScriptName());
  }
}

このスクリプトはオブジェクトにPINを設定した後、自分自身を削除します。
PINを秘密にするという観点からするとこの方法は効果的です。
もっとも、設定した本人がPINを忘れてしまったりするとリモートロードできなくなりますがｗ
【修正】商品に自己消滅型PIN設定スクリプトを組み込んだ場合、商品を販売した時点（手渡ししても同様）でオブジェクトのコピーが作られ、PINがクリアされてしまうため、正しくリモートロードできなくなります。自己消滅型のPIN設定は商品には向いていません。
さて次に・・・。
PINが設定されたオブジェクトに対し、スクリプトをロードするにはllRemoteLoadScriptPin関数です。

  llRemoteLoadScriptPin(key target, string name, integer pin, integer running, integer start_param);

引数が多いので順番に説明します。

key target

リモートロード先のターゲットprimのUUIDを指定します。
「どのオブジェクトに」ロードするのかを指定する引数です。

string name

リモートロードするスクリプトの名前を指定します。
「どのスクリプトを」ロードするのかを指定する引数です。
もちろんこのスクリプトはロード元のオブジェクトのコンテンツ内に無ければいけません。
また、スクリプトがNo Copyになってたりすると、「コピー」ではなく「移動」されてしまいますので注意して下さい。

ロード先のコンテンツ内に同一名称のスクリプトがあった場合は上書きされます。
同一名称のスクリプトが無ければ、コピーになります。

integer pin

PINを指定します。
先ほどのllSetRemoteScriptAccessPin関数で設定されたPINを使って下さい。

integer running

リモートロードしたスクリプトをすぐに動かしたいならTRUEです。
FALSEにすると、ロードされたスクリプトは停止状態になります。
停止状態のスクリプトをあとで動かすにはllSetScriptState関数を使います。

integer start_param

リモートロードしたスクリプトに渡すパラメータです。
任意の整数を指定できますが、特に渡したい情報がなければ0などの適当な整数でOKです。
このパラメータは、ロードされたスクリプトでllGetStartParameter関数を使って取得できます。

具体例を示しておきます。

  llRemoteLoadScriptPin("66864f3c-e095-d9c8-058d-d6575e6ed1b8",
    "main", 12345, TRUE, 2);

この例では、UUID"66864f3c-e095-d9c8-058d-d6575e6ed1b8"で特定されるオブジェクトに対して、"main"という名前のスクリプトをロードします。
PINは先ほど例示したスクリプトで設定した値、12345にしてみました。
ロードされたスクリプト"main"は即座に動き出します（defaultステートのstate_entryが発動します）。
"main"の中でllGetStartParameter()関数を使うと、2が取得されます。

なお、llRemoteLoadScriptPin関数でリモートロードを行う際は、ターゲットが同じSIM内になければなりません。

アップデート装置

さて、ではリモートロードの機能を使って、商品のアップデートを行う装置を作ってみましょう。
装置の外観はどんなものでも構いません。
お好みで自動販売機っぽいものや、スーパーコンピュータっぽいもの、あるいはただの球体でもいいです。

商品には以下のような２つのスクリプトを仕込みます。
PINは12345としておきますが、実際に使う場合には独自の数値に変更して下さい。

商品用スクリプトその１：PIN設定

integer pin = 12345;

default {
  state_entry(){
    llSetRemoteScriptAccessPin(pin);
  }
}

商品用スクリプトその２：アップデートコマンド処理

integer command_channel = 1;
integer remort_channel = -7;
integer handle;

default {
  state_entry(){
    handle = llListen(command_channel, "", llGetOwner(), "update");
  }

  listen(integer ch, string nm, key id, string msg){
    if (ch == command_channel && msg == "update"){
      llSay(remort_channel,"update");
    }
  }
}

一つ目のスクリプトは先ほども例示したPIN設定用のスクリプトです。
二つ目のほうは、ユーザーの「/1 update」という発言をlistenし、アップデートマシンに対してチャンネル-1で"update"と発言するだけのスクリプトです。
これがアップデートのきっかけとなります。

アップデート側のスクリプトは、オブジェクトの"update"という発言をlistenして動き出すようにします。
以下にアップデート側のスクリプトを示します。

リモートロードするスクリプトは、"main"と"sub"という名前のスクリプトにしてみました。
"main"と"sub"のスクリプトは、アップデート装置のコンテンツ内に入れておかなければなりません。

integer pin = 12345;
integer remort_channel = -7;
integer handle;

default {
  state_entry(){
    handle = llListen(remort_channel, "", NULL_KEY, "update");
  }

  listen(integer ch, string nm, key id, string msg){
    if (ch == remort_channel && msg == "update"){
      llSay(0, "Update process start. Please wait... > "
        + llKey2Name(llGetOwnerKey(id)));
      llRemoteLoadScriptPin(id,"main", pin, TRUE, 0);
      llRemoteLoadScriptPin(id,"sub", pin, TRUE, 0);
      llSay(0, "Update complete! > "
        + llKey2Name(llGetOwnerKey(id)));
    }
  }
}

こんな感じです。
llRemoteLoadScriptPin関数は、実行に3秒ほどかかります。
"main"と"sub"の二つをリモートロードしていますので、6秒ほどかかることになります。
その間、ユーザーがどこかに行ってしまわないよう、
「アップデート開始、ちょっと待ってね」
というメッセージを出すようにしました。
アップデート完了後には、「終わったよ」のメッセージです。

もしも商品の中に"main"と"sub"のスクリプトが存在しなければ、新たにコピーされることになります。
すでに"main"と"sub"がある場合は上書きです。

なお、注意すべき点は商品のパーミッションです。
アップデート装置のオーナーと商品のオーナーが異なる場合、商品がmod可でなければリモートロードは実行できません。
また、アタッチされた状態でも動作しませんので、商品を一度地面に置く必要があります。

アップデート装置と商品のオーナーが同じ場合はこの制限がありません。
アップデート装置そのものをフリー配布し、商品のオーナーにrezしてもらうと、mod不可の商品やアタッチメントでもリモートロードが可能になります。
この辺りは配布方法の工夫が必要です。

以上、最もシンプルなアップデート用のスクリプトでした。

データ保存

リモートロードを応用すると「データ保存」の仕組みも作れます。
RPGシステムなどで便利なセーブ＆ロードが実現可能なわけです。

仕組みは以下の通り。

データ管理：
・データ管理用のスクリプトを用意し、保存すべきデータは全てこのスクリプト内に保持する

セーブ：
・セーブ用オブジェクトをrezし、データ管理用スクリプトをリモートロードする

ロード：
・セーブ用オブジェクトからデータ管理用スクリプトをリモートロードで戻す

※一度投稿した後、読み直したらものすごくわかりにくかったので図示してみました（＾＾；




まずデータ管理用スクリプトですが、単純なのは以下のような構造です。

【データ保管用スクリプト】（名称"data"で作成）

list data=[];

default {
  
  link_message(integer sender, integer num,string str, key id){
    if (str == "set"){
      integer i = llListFindList(data, [(string)id]);
      if ( i != -1){
         data = llListReplaceList(data, [(string)id, num], i, i+1);
      }else{
        data += [(string)id, num];
      }
    }else if (str == "get"){
      integer i = llListFindList(data, [(string)id]);
      if ( i != -1){
         llMessageLinked(sender, llList2Integer(data, i+1), "ret", id);
      }else{
         llMessageLinked(sender, num, "ret", id);
      }
    }
  }
  
}

データのやり取りはリンクメッセージを使って行います。
リンクメッセージで文字列"set"を受け取ったときは、キーidと整数値numをワンセットのデータとしてリスト型変数dataに保存します。
"get"を受け取ったときは、キーidで指定されたデータが保管されているかどうかを調べ、見つかれば対応するnumをリンクメッセージで送り返します。
・・・これ、整数値しか保管できませんけどもね（＾＾；

次のようなユーザー関数を用意しておくと楽かもしれません。

set_value(string keyword, integer value){
  llMessageLinked(LINK_THIS, value, "set", (key)keyword);
}

get_value(string keyword, integer default_value){
  llMessageLinked(LINK_THIS, default_value, "get", (key)keyword);
}

default {
  state_entry(){
    set_value("test", 128);
  }
  
  touch_start(integer detected){
    get_value("test", 0);
  }
  
  link_message(integer sender, integer num, string str, key id){
    if (str == "ret"){
      llSay(0, "Keyword:" + (string)id + "=" + (string)num);
    }
  }
}

この例ではまず最初に"test"というキーワードで値128を保管します。
タッチされると"test"というキーワードで保管されているデータを探し、見つかった値をsayします。
正しく128という整数値が保管されていればOKです。

次に、セーブとロードの仕組みです。
まずは保存用オブジェクトを用意します。
外観は何でもかまいません。CD型なり磁気テープ型なりメモリスティック型なりクリスタルなり、お好みで作ってください。
保存用オブジェクトの名前を"save data"とし、以下のスクリプトを組み込みます。

【保存用オブジェクトのスクリプト】

integer pin = 12345;
integer channel = -7;
integer handle;
string script_name = "data";

default {
  state_entry(){
    llSetRemoteScriptAccessPin(pin);
  }
  
  on_rez(integer i){
    if (i == 1){
      llSetObjectName(llGetObjectName() + "(" + llGetTimestamp() + ")");
    }
  }
  
  touch_start(integer detected){
    if (llDetectedKey(0) == llGetOwner()){
      handle = llListen(channel, "", NULL_KEY, "data load");
      llSay(channel, "data load");
    }
  }
  
  listen(integer ch, string nm, key id, string msg){
    if (msg == "data load"
        && id != llGetKey()
        && llGetOwnerKey(id) == llGetOwner()){
      llSay(0, "Data load process start. Please wait... ");
      llRemoteLoadScriptPin(id,script_name , pin, TRUE, 0);
      llSay(0, "Data load complete! ");
      llDie();
    }
  }
}

state_entryイベントとon_rezイベントはセーブ時に必要な機能を実装したものです。
touch_startイベントとlistenイベントはロード時に使われます。

まずstate_entryイベントではPINを設定し、データ保管用スクリプトを受け入れ可能にしています。
on_rezイベントではオブジェクト名の後ろに現在時刻を付与し、いつ保存されたデータなのかが判断できるようにしているだけです。

保存用オブジェクトがオーナーにタッチされると、チャンネル-7でlistenを開始し、"data load"と発言します。
これを本体側で受信し、本体もまた"data load"と発言するようにします。
すると保存用オブジェクトのlistenイベントが発動し、スクリプト"data"を本体へとリモートロードするようになっています。

ロード後は保存用オブジェクトは消滅します。
また、ゴミとして放置されることのないよう、保存用オブジェクトは一時的オブジェクトにしておくと良いかもしれません。

話が前後しますが、次に本体側のスクリプトです。
本体側では、主にセーブ時の処理を実装します。
本体のコンテンツには保存用オブジェクト"save data"と、先ほどのデータ保管用スクリプトを"data"という名前で入れておく必要があります。

【本体用スクリプト】

integer pin = 12345;
integer channel = -7;
integer handle;
string script_name = "data";
string dataobject_name = "save data";

default {
  state_entry(){
    llSetRemoteScriptAccessPin(pin);
    handle = llListen(channel, "", NULL_KEY, "");
  }
  
  touch_start(integer detected){
    if (llDetectedKey(0) == llGetOwner()){
      llRezObject(dataobject_name, llGetPos() + <1.0,0.0,0.0>,
        ZERO_VECTOR, ZERO_ROTATION, );
    }
  }
  
  object_rez(key id){
    llSleep(1.0);
    llSay(0, "Data save process start. Please wait... ");
    llRemoteLoadScriptPin(id,script_name , pin, TRUE, 0);
    llSay(0, "Data save complete! Take '" + dataobject_name + "'.");
  }
  
  listen(integer ch, string nm, key id, string msg){
    if (msg == "data load"
        && llGetOwnerKey(id) == llGetOwner()){
      llSay(channel, "data load");
    }
  }
}

この例ではタッチでセーブが実行されるようにしてありますが、実際に使うときにはチャットコマンド等に変更すべきでしょう。
タッチされると近くに保存用オブジェクト"save data"をrezします。
rezが完了するとobject_rezイベントが発生します。
1秒のウエイトが入れてあるのは保存用オブジェクト"save data"側でPINが正しく設定されるのを待つためです。
そしてrezした保存用オブジェクト"save data"に対して、データ保管用スクリプト"data"をリモートロードします。
これでデータが退避されたので、
「セーブ終わったよ！"save data"オブジェクトを拾っておいてね！」
とメッセージを出します。

一方ロード時には、保存用オブジェクト"save data"から"data load"という発言が来るので、本体側からもこれに答えて"data load"という発言を返すだけです。
あとは保存用オブジェクトのほうからデータ保管用スクリプト"data"がリモートロードされてきます。